MTM指標（動量線指標）用于衡量價格的動量和趨勢，以判斷未來價格的變化。計算方法很簡單，用當前價格減去一段時間（通常為12日）前的價格，計算得到的差值的正負和大小，可以判斷可能的趨勢改變以及價格的相對強勢或弱勢。

MTM指標可以用來確認趨勢，當MTM指標為正時，表明當前價格較一段時間前的價格高，顯示出一定的上升動量，如果持續(xù)為正，表示價格處于上漲趨勢；當MTM指標為負時，表明當前價格較一段時間前的價格低，顯示出一定的下降動量，如果持續(xù)為負，表示價格處于下跌趨勢。

此外MTM指標還可以用來識別趨勢反轉，當MTM指標由負轉正，表明多頭力量正在增強，價格可能開始上漲；當MTM指標由正數轉為負數，表明空頭力量在增強，價格可能開始下跌。

另外MTM指標也可以用來判斷背離，當價格在上漲行情中創(chuàng)出新高，而MTM指標卻沒有創(chuàng)新高，這樣價格和MTM指標就形成了頂背離，意味上漲動量減弱，此時需要關注調整或反轉風險。當價格在下跌行情中創(chuàng)出新低，而MTM指標卻沒有創(chuàng)新低，價格與MTM指標形成底背離，意味下跌動量減弱，此時應注意反彈或者反轉的可能。

一、MTM副圖指標

MTM計算公式：

MTM=今日收盤價-N日前的收盤價

通達信軟件中自帶MTM指標，在K線圖界面，輸入“MTM”，就可以加載到副圖，白線是MTM，黃線是MTM均線。MTM不平滑，和均線經常交叉，不利于后續(xù)編寫背離指標，因此本文改為兩條MTM均線。（對比如下圖）

MTM:=C-REF(C,12);

MTMMA1:EMA(MTM,5);

MTMMA2:EMA(MTM,10);

二、MTM底背離主圖指標公式

MTM:=C-REF(C,12);

MTMMA1:=EMA(MTM,5);{5日MTM均線}

MTMMA2:=EMA(MTM,10);{10日MTM均線}

JC:=CROSS(MTMMA1,MTMMA2);{金叉}

SC:=CROSS(MTMMA2,MTMMA1);{死叉}

T1:=BARSLAST(SC);{上一次死叉到當前的周期數}

T2:=SUMBARS(SC,2);{向前累計兩次死叉到當前的周期數}

LL1:=LLV(L,T1+1);{一次死叉以來的最低價}

LL2:=LLV(L,T2);{向前累計兩次死叉以來的最低價}

MTM1:=LLV(MTMMA1,T1+1);{一次死叉以來的最低MTMMA1均線值}

MTM2:=LLV(MTMMA1,T2);{向前累計兩次死叉以來的最低MTMMA1均線值}

XG:=LL1=LL2 AND MTM1>MTM2 AND JC;{最低價創(chuàng)新低，MTMMA1不創(chuàng)新低，金叉觸發(fā)信號}

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLOR117777;

STICKLINE(XG,C,O,2.5,0),COLOR119999;

STICKLINE(XG,C,O,2,0),COLOR11BBBB;

STICKLINE(XG,C,O,1.5,0),COLOR11DDDD;

STICKLINE(XG,C,O,1,0),COLOR44FFFF;

DRAWICON(XG,L,11);

三、MTM底背離選股公式

MTM:=C-REF(C,12);

MTMMA1:=EMA(MTM,5);

MTMMA2:=EMA(MTM,10);

JC:=CROSS(MTMMA1,MTMMA2);

SC:=CROSS(MTMMA2,MTMMA1);

T1:=BARSLAST(SC);

T2:=SUMBARS(SC,2);

LL1:=LLV(L,T1+1);

LL2:=LLV(L,T2);

MTM1:=LLV(MTMMA1,T1+1);

MTM2:=LLV(MTMMA1,T2);

XG:LL1=LL2 AND MTM1>MTM2 AND JC;

最后說明一下，下跌趨勢風險很大，反彈之后很可能繼續(xù)下跌。單一方法產生的信號不一定靠譜，需要謹慎辨別并結合其他方法綜合決策。

?

關注技術Pie，學習更多通達信指標公式編寫知識。版權所有，轉載請注明出處。

友情提醒：本文僅供學習交流技術指標公式，不構成任何投資建議。投資有風險，入市需謹慎。